topas wiki

— Alan Coelho 2016/03/10 15:26

Version 5 upwards; Mass attenuation coefficient corresponding to XRF results.

  test_txamples\XRF-MAC.INP

The two lines below marked Line 1 and Line 3 outputs the same phase_MAC. One is calculated from the str and the other from the dummy_str; the latter uses the elemental results from the first str but which could be from an XRF analysis. The two macros AW_Ce and AW_O are atomic weights for Ce and O respectively; these values come from the file isotopes.txt. This example could easily be extended to many elements. The denominator in Line 2 should probably correspond to the element with the highest weight percent.

macro AW_Ce { 140.116 } /* Atomic weight from ISOTOPES.TXT */
macro AW_O  { 15.9994 } /* Atomic weight from ISOTOPES.TXT */
macro e_Ce  { 81.408 } /* elemental wt% from XRF */
macro e_O   { 18.592 } /* elemental wt% from XRF */
 
r_wp 0
XDD(ceo2)
   CuKa5(0.0001)
   Radius(173)
   LP_Factor(17)
   Full_Axial_Model(12, 20, 12, 5.1, @ 7)
   Divergence(1)
   Slit_Width(.1)
   bkg @ 0 0 0 0 0
   One_on_X(@, 1000)
   Zero_Error(@, 0)
   elemental_composition
   {
                 Rietveld
     CE            81.408
     O             18.592
   }
   str
      space_group F_M_3_M
      phase_name CeO2
      scale @ 0.0014503208
      Cubic(@ 5.41)
      site  Ce1                       occ Ce+4  1 beq @  0.2028 
      site  O1  x 0.25 y 0.25 z 0.25  occ O-2   1 beq @  0.5959 
 
      CS_L(@, 300)
      Strain_L(@, 0.1)
      MVW(0, 0, 0)
      Phase_LAC_1_on_cm(0)
 
      /* Mass attenuation coefficient calculated by Rietveld refinement */
      prm = Get(phase_MAC); : 301.01797 /* Line 1 */
 
   dummy_str space_group P1 scale 0 a 1 b 1 c 1
 
      site  Ce  occ Ce+4 = 1;
      site  O   occ O-2  = (e_O / e_Ce) AW_Ce / AW_O; /* Line 2 */
 
      /* Mass attenuation coefficient corresponding to XRF results */
      prm = Get(phase_MAC); : 301.01797 /* Line 3 */